GUICtrlCreateAvi
Erstellt ein AVI Video-Control für die GUI.
GUICtrlCreateAvi ( filename, subfileid, left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
Parameter
| filename | Der Dateiname des Videos. Nur .avi-Dateien werden unterstützt. |
| subfileid | Die ID des Subfiles, das verwendet werden soll. Besteht die Datei nur aus einem Video, ist 0 zu verwenden. |
| left | Die linke Seite des Controls. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet. |
| top | Die Oberkante des Controls. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet. |
| width | [optional] Die Breite des Controls (voreingestellt ist die zuvor verwendete Breite). |
| height | [optional] Die Höhe des Controls (voreingestellt ist die zuvor verwendete Höhe). |
| style | [optional] Legt den Stil des Controls fest. Siehe Anhang GUI-Stile für Controls. Standard (-1) : $ACS_TRANSPARENT $ACS_TRANSPARENT wird immer verwendet, solange nicht $ACS_NONTRANSPARENT spezifiziert ist. |
| exStyle | [optional] Legt den erweiterten Stil des Controls fest. Siehe Tabelle der erweiterten Stile. |
Rückgabewert
| Erfolg: | Die Identifikationsnummer (Control-ID) des neuen Controls. |
| Fehler: | 0. |
Bemerkungen
Um den Wert des Controls zu erhalten, siehe GUICtrlRead().
Um Informationen im Control zu setzen oder zu verändern, siehe GUICtrlUpdate... Funktionen.
Um das Video zu starten, sobald das Control erzeugt wurde, verwendet man den Stil $ACS_AUTOPLAY.
Man kann die Animation starten und stoppen, indem man den Status mit GUICtrlSetState() auf 1 oder 0 setzt. Siehe Beispiel.
Um weitere Stile zusätzlich zum Standardstil zu verwenden, ist BitOR($GUI_SS_DEFAULT_AVI, newstyle, ... ) zu benutzen.
Um die oben angegebenen Werte verwenden zu können, muss #include <AVIConstants.au3> in das Skript eingefügt werden.
Als Standard für das Verhalten des Controls (bzgl. Größe und/oder Position) bei Größenänderung der GUI gilt $GUI_DOCKSIZE. (Größe wird nicht geändert.)
Mögliche Resizing-Parameter siehe GUICtrlSetResizing.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
GUICoordMode (option), GUICtrlUpdate..., GUIGetMsg
Beispiel
#include <GUIConstantsEx.au3>
Example()
Func Example()
; Erstellt eine GUI mit verschiedenen Controls.
Local $hGui = GUICreate("Beispiel", 300, 200)
; Erstellt ein Animationscontrol.
Local $idAnimation = GUICtrlCreateAvi(@SystemDir & "\shell32.dll", 165, 15, 0, 300)
Local $idStart = GUICtrlCreateButton("Start", 60, 150, 85, 25)
Local $idStop = GUICtrlCreateButton("Stop", 160, 150, 85, 25)
; Zeigt die GUI
GUISetState(@SW_SHOW, $hGui)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
Case $idStart ; Startet die Animation.
GUICtrlSetState($idAnimation, $GUI_AVISTART)
Case $idStop ; Beendet die Animation.
GUICtrlSetState($idAnimation, $GUI_AVISTOP)
EndSwitch
WEnd
; Löscht die vorherige GUI und alle Controls.
GUIDelete($hGui)
EndFunc ;==>Example